bat脚本实现快速更改IP

2301_80127209

已于 2024-06-14 18:31:58 修改

阅读量3.7k

点赞数 5

CC 4.0 BY-SA版权

文章标签： tcp/ip 网络 linux

于 2024-06-13 16:54:50 首次发布

本文链接：https://blog.csdn.net/2301_80127209/article/details/139654815

大家平时在运维工作的过程中经常会碰到需要修改静态IP的情况，每次去到不同的客户那就要手动修改一次静态IP，非常的麻烦，这个bat脚本可以快速修改静态IP，帮助广大懒狗兄弟们。（管理员身份运行）
如遇到乱码问题，用记事本另存为bat，编码格式改为ANSI。

运行截图：

@echo off
rem //设置网卡名称
set NAME="网卡名称"
rem //以下属性值可以根据需要更改
set ADDR1=192.168.x.x
set ADDR2=192.168.x.x
set MASK=255.255.255.0
set GATEWAY1=192.168.x.254
set GATEWAY2=192.168.x.1
set DNS1=8.8.8.8
set DNS2=x.x.x.x
echo 请输入网络序号：
echo 1 上专用网
echo 2 上互联网
echo 3 动态
echo 4 退出
echo 请选择后回车：
choice /c 1234 /n
if %errorlevel%==1 goto 1
if %errorlevel%==2 goto 2
if %errorlevel%==3 goto 3
if %errorlevel%==4 goto 4
:1
echo 正在设置静态IP,请稍等…
netsh interface ipv4 set address name=%NAME% source=static addr=%ADDR1% mask=%MASK% gateway=%GATEWAY1% gwmetric=0 >nul
echo IP地址 = %ADDR1%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY1%
netsh interface ipv4 set dns name=%NAME% source=static addr=%DNS1% register=PRIMARY >nul
echo 首选DNS = %DNS1%
netsh interface ipv4 add dns name=%NAME% addr=%DNS2% index=2 >nul
echo 备用DNS = %DNS2%
echo 静态IP已设置!
pause
goto 4
:2
echo 正在设置静态IP,请稍等…
netsh interface ipv4 set address name=%NAME% source=static addr=%ADDR2% mask=%MASK% gateway=%GATEWAY2% gwmetric=0 >nul
echo IP地址 = %ADDR2%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY2%
netsh interface ipv4 set dns name=%NAME% source=static addr=%DNS2% register=PRIMARY >nul
echo 首选DNS = %DNS2%
netsh interface ipv4 add dns name=%NAME% addr=%DNS1% index=2 >nul
echo 备用DNS = %DNS1%
echo 静态IP已设置!
pause
goto 4
:3
netsh interface ip set address name="网卡名称" source=dhcp
netsh interface ip set dns name="网卡名称" source=dhcp
echo DHCP已设置
pause
goto 4
:4
exit
申明：本账号所分享内容仅用于网络安全技术讨论，切勿用于违法途径，所有渗透都需获取授权，违者后果自行承担，与本号及作者无关，请谨记守法。