constraintlayout/constraintlayout-compose/build.gradle

/*
 * Copyright (C) 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.AndroidXComposePlugin
import androidx.build.LibraryType
import androidx.build.Publish

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("AndroidXComposePlugin")
}

AndroidXComposePlugin.applyAndConfigureKotlinPlugin(project)

dependencies {
    if(!AndroidXComposePlugin.isMultiplatformEnabled(project)) {
        implementation(project(":compose:ui:ui"))
        implementation(project(":compose:ui:ui-unit"))
        implementation(project(":compose:ui:ui-util"))
        implementation(project(":compose:foundation:foundation"))
        implementation(project(":compose:foundation:foundation-layout"))

        implementation(project(":constraintlayout:constraintlayout-core"))

        androidTestImplementation(project(":compose:material:material"))
        androidTestImplementation(project(":compose:ui:ui-test"))
        androidTestImplementation(project(":compose:ui:ui-test-junit4"))
        androidTestImplementation(project(":compose:ui:ui-test-manifest"))
        androidTestImplementation(project(":activity:activity"))

        androidTestImplementation(libs.kotlinTest)
        androidTestImplementation(libs.testRules)
        androidTestImplementation(libs.testRunner)
        androidTestImplementation(libs.junit)
    }
}

if(AndroidXComposePlugin.isMultiplatformEnabled(project)) {
    androidXComposeMultiplatform {
        android()
        desktop()
    }

    kotlin {
        /*
         * When updating dependencies, make sure to make the an an analogous update in the
         * corresponding block above
         */
        sourceSets {
            commonMain.dependencies {
//                implementation(libs.kotlinStdlibCommon)

                implementation(project(":compose:ui:ui"))
                implementation(project(":compose:ui:ui-unit"))
                implementation(project(":compose:ui:ui-util"))
                implementation(project(":compose:foundation:foundation"))
                implementation(project(":compose:foundation:foundation-layout"))
                implementation(project(":constraintlayout:constraintlayout-core"))

            }

            androidMain.dependencies {
                api("androidx.annotation:annotation:1.1.0")
                implementation("androidx.core:core-ktx:1.5.0")
            }

            desktopMain.dependencies {
                implementation(libs.kotlinStdlib)
            }

            // TODO(b/214407011): These dependencies leak into instrumented tests as well. If you
            //  need to add Robolectric (which must be kept out of androidAndroidTest), use a top
            //  level dependencies block instead:
            //  `dependencies { testImplementation(libs.robolectric) }`
            androidTest.dependencies {
                implementation(libs.testRules)
                implementation(libs.testRunner)
                implementation(libs.junit)
            }

            androidAndroidTest.dependencies {
                implementation(libs.kotlinTest)
                implementation(libs.testRules)
                implementation(libs.testRunner)
                implementation(libs.junit)
                implementation(libs.truth)
                implementation(project(":compose:foundation:foundation"))
                implementation(project(":compose:material:material"))
                implementation(project(":compose:ui:ui-test-junit4"))
                implementation(project(":compose:ui:ui-test-manifest"))
                implementation(project(":compose:test-utils"))
            }
        }
    }
}

androidx {
    name = "Android ConstraintLayout Compose Library"
    type = LibraryType.PUBLISHED_LIBRARY
    mavenVersion = LibraryVersions.CONSTRAINTLAYOUT_COMPOSE
    mavenGroup = LibraryGroups.CONSTRAINTLAYOUT
    inceptionYear = "2022"
    description = "This library offers a flexible and adaptable way to position and animate widgets in Compose"
}

android {
    namespace "androidx.constraintlayout.compose"
}