components/view_manager/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")
import("//testing/test.gni")
import("//third_party/mojo/src/mojo/public/mojo_application.gni")

mojo_native_application("view_manager") {
  sources = [
    "main.cc",
    "view_manager_app.cc",
    "view_manager_app.h",
  ]

  deps = [
    ":view_manager_lib",
    "//base",
    "//components/view_manager/public/interfaces",
    "//components/window_manager/public/interfaces",
    "//mojo/application",
    "//mojo/common:tracing_impl",
    "//mojo/converters/geometry",
    "//mojo/environment:chromium",
    "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
  ]
}

source_set("view_manager_lib") {
  sources = [
    "access_policy.h",
    "access_policy_delegate.h",
    "animation_runner.cc",
    "animation_runner.h",
    "animation_runner_observer.h",
    "client_connection.cc",
    "client_connection.h",
    "connection_manager.cc",
    "connection_manager.h",
    "connection_manager_delegate.h",
    "default_access_policy.cc",
    "default_access_policy.h",
    "display_manager.cc",
    "display_manager.h",
    "event_dispatcher.cc",
    "event_dispatcher.h",
    "focus_controller.cc",
    "focus_controller.h",
    "focus_controller_delegate.h",
    "gesture_manager.cc",
    "gesture_manager.h",
    "gesture_manager_delegate.h",
    "scheduled_animation_group.cc",
    "scheduled_animation_group.h",
    "server_view.cc",
    "server_view.h",
    "server_view_delegate.h",
    "server_view_drawn_tracker.cc",
    "server_view_drawn_tracker.h",
    "server_view_drawn_tracker_observer.h",
    "server_view_observer.h",
    "view_coordinate_conversions.cc",
    "view_coordinate_conversions.h",
    "view_locator.cc",
    "view_locator.h",
    "view_manager_service_impl.cc",
    "view_manager_service_impl.h",
    "window_manager_access_policy.cc",
    "window_manager_access_policy.h",
  ]

  public_deps = [
    "//components/view_manager/public/cpp",
  ]

  deps = [
    "//base",
    "//cc/surfaces",
    "//cc/surfaces:surface_id",
    "//components/native_viewport/public/interfaces",
    "//components/surfaces/public/interfaces",
    "//components/view_manager/public/cpp:common",
    "//components/view_manager/public/interfaces",
    "//components/window_manager/public/interfaces",
    "//mojo/application",
    "//mojo/common",
    "//mojo/converters/geometry",
    "//mojo/converters/input_events",
    "//mojo/converters/surfaces",
    "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
    "//third_party/mojo/src/mojo/public/cpp/bindings:callback",
    "//third_party/mojo/src/mojo/public/interfaces/application",
    "//ui/mojo/geometry:interfaces",
    "//ui/mojo/events:interfaces",
    "//ui/gfx",
    "//ui/gfx/geometry",
  ]
}

source_set("test_support") {
  testonly = true

  sources = [
    "test_change_tracker.cc",
    "test_change_tracker.h",
  ]

  deps = [
    "//base",
    "//components/view_manager/public/cpp",
    "//components/view_manager/public/cpp:common",
    "//components/view_manager/public/interfaces",
    "//mojo/common",
    "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
    "//ui/mojo/geometry:interfaces",
  ]
}

test("view_manager_service_unittests") {
  sources = [
    "animation_runner_unittest.cc",
    "focus_controller_unittest.cc",
    "gesture_manager_unittest.cc",
    "scheduled_animation_group_unittest.cc",
    "server_view_drawn_tracker_unittest.cc",
    "test_server_view_delegate.cc",
    "test_server_view_delegate.h",
    "view_coordinate_conversions_unittest.cc",
    "view_manager_service_unittest.cc",
  ]

  deps = [
    ":test_support",
    ":view_manager_lib",
    "//base",
    "//base/test:test_config",
    "//components/native_viewport/public/cpp:args",
    "//components/view_manager/public/cpp:common",
    "//components/view_manager/public/interfaces",
    "//components/window_manager/public/interfaces",
    "//mojo/converters/geometry",
    "//mojo/converters/input_events",
    "//mojo/environment:chromium",
    "//third_party/mojo/src/mojo/edk/test:run_all_unittests",
    "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
    "//third_party/mojo/src/mojo/public/interfaces/application",
    "//ui/mojo/geometry:interfaces",
    "//ui/mojo/events:interfaces",
    "//testing/gtest",
    "//ui/gfx",
    "//ui/gfx:test_support",
    "//ui/gfx/geometry",
  ]

  if (!is_android) {  # TODO(GYP) Enable on Android when osmesa links.
    deps += [ "//third_party/mesa:osmesa" ]
  }
}

mojo_native_application("apptests") {
  output_name = "view_manager_apptests"
  testonly = true

  sources = [
    "view_manager_client_apptest.cc",
    "view_manager_service_apptest.cc",
  ]

  deps = [
    ":test_support",
    "//base",
    "//base/test:test_config",
    "//components/view_manager/public/cpp",
    "//components/view_manager/public/interfaces",
    "//components/window_manager/public/interfaces",
    "//mojo/application",
    "//mojo/application:test_support",
    "//mojo/common",
    "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
    "//ui/mojo/geometry:interfaces",
    "//ui/mojo/geometry:util",
  ]
}