third_party/blink/public/mojom/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

# This target includes all mojom interfaces which can be used from
# Source/platform. In particular these mojom interfaces can't use types that
# are typemapped to a type in Source/core.
mojom("mojom_platform") {
  sources = [
    "array_buffer/array_buffer_contents.mojom",
    "blob/blob.mojom",
    "blob/blob_registry.mojom",
    "blob/blob_url_store.mojom",
    "blob/data_element.mojom",
    "blob/serialized_blob.mojom",
    "clipboard/clipboard.mojom",
    "color_chooser/color_chooser.mojom",
    "feature_policy/feature_policy.mojom",
    "file/file_utilities.mojom",
    "leak_detector/leak_detector.mojom",
    "loader/prefetch_url_loader_service.mojom",
    "net/ip_address_space.mojom",
    "page/page_visibility_state.mojom",
    "quota/quota_dispatcher_host.mojom",
    "quota/quota_types.mojom",
    "service_worker/navigation_preload_state.mojom",
    "service_worker/service_worker_client.mojom",
    "service_worker/service_worker_error_type.mojom",
    "service_worker/service_worker_event_status.mojom",
    "service_worker/service_worker_installed_scripts_manager.mojom",
    "service_worker/service_worker_provider_type.mojom",
    "service_worker/service_worker_state.mojom",
    "service_worker/service_worker_stream_handle.mojom",
    "shared_worker/shared_worker_creation_context_type.mojom",
    "use_counter/css_property_id.mojom",
    "web_package/web_package_internals.mojom",
  ]

  public_deps = [
    "//mojo/public/mojom/base",
    "//services/network/public/mojom",

    # TODO(https://crbug.com/822804): Remove when mojom bindings deps checks
    # get fixed.
    "//services/network/public/mojom:data_pipe_interfaces",
    "//ui/gfx/geometry/mojo",
    "//url/mojom:url_mojom_gurl",
    "//url/mojom:url_mojom_origin",
  ]

  export_class_attribute = "BLINK_COMMON_EXPORT"
  export_define = "BLINK_COMMON_IMPLEMENTATION=1"
  export_header = "third_party/blink/common/common_export.h"

  export_class_attribute_blink = "PLATFORM_EXPORT"
  export_define_blink = "BLINK_PLATFORM_IMPLEMENTATION=1"
  export_header_blink = "third_party/blink/renderer/platform/platform_export.h"
}

# This target can include mojom interfaces which do use types that are
# typemapped to a type in Source/core. This also means these interfaces are not
# available from Source/platform.
# Note that service_worker_object.mojom and service_worker.mojom depend
# on message_port.mojom, and service_worker_registration.mojom depends
# on service_worker_object.mojom, so we put these three service worker
# mojom files here rather than mojom_platform target.
# In future we may have a separate mojom target for the things that may have
# modules dependencies if it looks necessary, at that time we can put all of
# those high-level service worker mojom files there.
mojom("mojom_core") {
  sources = [
    "message_port/message_port.mojom",
    "service_worker/service_worker.mojom",
    "service_worker/service_worker_object.mojom",
    "service_worker/service_worker_registration.mojom",
  ]

  public_deps = [
    ":mojom_platform",
    "//mojo/public/mojom/base",
    "//skia/public/interfaces",
    "//url/mojom:url_mojom_gurl",
  ]

  overridden_deps_blink = [ ":mojom_platform" ]
  component_deps_blink = [ "//third_party/blink/renderer/platform" ]

  export_class_attribute = "BLINK_COMMON_EXPORT"
  export_define = "BLINK_COMMON_IMPLEMENTATION=1"
  export_header = "third_party/blink/common/common_export.h"

  export_class_attribute_blink = "CORE_EXPORT"
  export_define_blink = "BLINK_CORE_IMPLEMENTATION=1"
  export_header_blink = "third_party/blink/renderer/core/core_export.h"
}