front_end/panels/developer_resources/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../../../scripts/build/ninja/generate_css.gni")
import("../../../scripts/build/typescript/typescript.gni")
import("../visibility.gni")

generate_css("css_files") {
  sources = [
    "developerResourcesListView.css",
    "developerResourcesView.css",
  ]
}

devtools_module("developer_resources") {
  sources = [
    "DeveloperResourcesListView.ts",
    "DeveloperResourcesView.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/host:bundle",
    "../../core/i18n:bundle",
    "../../core/platform:bundle",
    "../../core/sdk:bundle",
    "../../models/text_utils:bundle",
    "../../ui/legacy:bundle",
    "../../ui/legacy/components/data_grid:bundle",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "developer_resources.ts"

  deps = [
    ":css_files",
    ":developer_resources",
  ]

  visibility = [
    ":*",
    "../../entrypoints/*",
  ]

  visibility += devtools_panels_visibility
}

devtools_entrypoint("meta") {
  entrypoint = "developer_resources-meta.ts"

  deps = [
    ":bundle",
    "../../core/i18n:bundle",
    "../../ui/legacy:bundle",
  ]

  visibility = [ "../../entrypoints/*" ]
}

ts_library("unittests") {
  testonly = true

  sources = [
    "DeveloperResourcesView.test.ts",
    "developer_resources.test.ts",
  ]

  deps = [
    ":bundle",
    "../../testing",
  ]
}