front_end/models/timeline_model/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../visibility.gni")

devtools_module("timeline_model") {
  sources = [
    "TimelineFrameModel.ts",
    "TimelineIRModel.ts",
    "TimelineJSProfile.ts",
    "TimelineModel.ts",
    "TimelineModelFilter.ts",
    "TimelineProfileTree.ts",
    "TracingLayerTree.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/i18n:bundle",
    "../../core/platform:bundle",
    "../../core/root:bundle",
    "../../core/sdk:bundle",
    "../../generated:protocol",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "timeline_model.ts"

  deps = [ ":timeline_model" ]

  visibility = [
    ":*",
    "../../../test/unittests/front_end/models/timeline_model/*",
    "../../panels/timeline/*",

    # TODO(crbug.com/1202788): Remove invalid dependents
    "../../ui/legacy/components/perf_ui/*",
  ]

  visibility += devtools_models_visibility
}

devtools_entrypoint("legacy") {
  entrypoint = "timeline_model-legacy.ts"

  deps = [ ":bundle" ]

  visibility = [ "../..:legacy_entrypoints" ]
}