front_end/panels/coverage/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../../../scripts/build/ninja/generate_css.gni")
import("../../../scripts/build/typescript/typescript.gni")
import("../visibility.gni")

generate_css("css_files") {
  sources = [
    "coverageListView.css",
    "coverageView.css",
  ]
}

devtools_module("coverage") {
  sources = [
    "CoverageDecorationManager.ts",
    "CoverageListView.ts",
    "CoverageModel.ts",
    "CoverageView.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/host:bundle",
    "../../core/i18n:bundle",
    "../../core/platform:bundle",
    "../../core/sdk:bundle",
    "../../models/bindings:bundle",
    "../../models/formatter:bundle",
    "../../models/text_utils:bundle",
    "../../models/workspace:bundle",
    "../../ui/legacy:bundle",
    "../../ui/legacy/components/data_grid:bundle",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "coverage.ts"

  deps = [
    ":coverage",
    ":css_files",
  ]

  visibility = [
    ":*",
    "../../entrypoints/*",
    "../sources/*",
    "../timeline/*",
  ]

  visibility += devtools_panels_visibility
}

devtools_entrypoint("meta") {
  entrypoint = "coverage-meta.ts"

  deps = [
    ":bundle",
    "../../core/i18n:bundle",
    "../../ui/legacy:bundle",
  ]

  visibility = [ "../../entrypoints/*" ]
}

ts_library("unittests") {
  testonly = true

  sources = [
    "CoverageDecorationManager.test.ts",
    "CoverageModel.test.ts",
    "CoverageView.test.ts",
  ]

  deps = [
    ":bundle",
    "../../core/common:bundle",
    "../../core/platform:bundle",
    "../../core/sdk:bundle",
    "../../models/bindings:bundle",
    "../../models/text_utils:bundle",
    "../../models/workspace:bundle",
    "../../testing",
  ]
}