front_end/panels/css_overview/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../../../scripts/build/ninja/generate_css.gni")
import("../../../scripts/build/typescript/typescript.gni")

generate_css("css_files") {
  sources = [
    "cssOverview.css",
    "cssOverviewCompletedView.css",
    "cssOverviewProcessingView.css",
    "cssOverviewSidebarPanel.css",
  ]
}

import("../visibility.gni")

devtools_module("css_overview") {
  sources = [
    "CSSOverviewCompletedView.ts",
    "CSSOverviewController.ts",
    "CSSOverviewModel.ts",
    "CSSOverviewPanel.ts",
    "CSSOverviewProcessingView.ts",
    "CSSOverviewSidebarPanel.ts",
    "CSSOverviewUnusedDeclarations.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/host:bundle",
    "../../core/i18n:bundle",
    "../../core/platform:bundle",
    "../../core/root:bundle",
    "../../core/sdk:bundle",
    "../../generated:protocol",
    "../../models/text_utils:bundle",
    "../../ui/components/icon_button:bundle",
    "../../ui/legacy:bundle",
    "../../ui/legacy/components/color_picker:bundle",
    "../../ui/legacy/components/data_grid:bundle",
    "../../ui/legacy/components/utils:bundle",
    "./components:bundle",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "css_overview.ts"

  deps = [
    ":css_files",
    ":css_overview",
  ]

  visibility = [
    ":*",
    "../../entrypoints/*",
    "../../ui/legacy/components/inline_editor/*",
  ]

  visibility += devtools_panels_visibility
}

devtools_entrypoint("meta") {
  entrypoint = "css_overview-meta.ts"

  deps = [
    ":bundle",
    "../../core/i18n:bundle",
    "../../ui/legacy:bundle",
  ]

  visibility = [ "../../entrypoints/*" ]
}

ts_library("unittests") {
  testonly = true

  sources = [ "CSSOverviewPanel.test.ts" ]

  deps = [
    ":bundle",
    "../../core/common:bundle",
    "../../core/protocol_client:bundle",
    "../../core/sdk:bundle",
    "../../generated:protocol",
    "../../testing",
    "../../ui/legacy:bundle",
  ]
}