front_end/entrypoints/inspector_main/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../../scripts/build/ninja/devtools_entrypoint.gni")
import("../../../scripts/build/ninja/devtools_module.gni")
import("../../../scripts/build/ninja/generate_css.gni")
import("../visibility.gni")

generate_css("css_files") {
  sources = [
    "nodeIcon.css",
    "outermostTargetSelector.css",
    "renderingOptions.css",
  ]
}

devtools_module("inspector_main") {
  sources = [
    "InspectorMain.ts",
    "OutermostTargetSelector.ts",
    "RenderingOptions.ts",
  ]

  deps = [
    "../../core/common:bundle",
    "../../core/host:bundle",
    "../../core/i18n:bundle",
    "../../core/root:bundle",
    "../../core/sdk:bundle",
    "../../generated:protocol",
    "../../panels/mobile_throttling:bundle",
    "../../ui/components/icon_button:bundle",
    "../../ui/legacy:bundle",
    "../../ui/legacy/components/utils:bundle",
  ]
}

devtools_entrypoint("bundle") {
  entrypoint = "inspector_main.ts"

  deps = [
    ":css_files",
    ":inspector_main",
  ]

  visibility = [
    ":*",
    "../../../test/unittests/front_end/entrypoints/missing_entrypoints/*",
    "../../../test/unittests/front_end/helpers/*",
    "../main/*",
  ]

  visibility += devtools_entrypoints_visibility
}

devtools_entrypoint("meta") {
  entrypoint = "inspector_main-meta.ts"

  deps = [ ":bundle" ]

  visibility = [
    "../../../test/unittests/front_end/helpers/*",
    "../devtools_app/*",
  ]
}